mirror of https://github.com/n-hys/bash.git
250 lines
9.5 KiB
Plaintext
250 lines
9.5 KiB
Plaintext
# lib-prefix.m4 serial 14
|
|
dnl Copyright (C) 2001-2005, 2008-2019 Free Software Foundation, Inc.
|
|
dnl This file is free software; the Free Software Foundation
|
|
dnl gives unlimited permission to copy and/or distribute it,
|
|
dnl with or without modifications, as long as this notice is preserved.
|
|
|
|
dnl From Bruno Haible.
|
|
|
|
dnl AC_LIB_PREFIX adds to the CPPFLAGS and LDFLAGS the flags that are needed
|
|
dnl to access previously installed libraries. The basic assumption is that
|
|
dnl a user will want packages to use other packages he previously installed
|
|
dnl with the same --prefix option.
|
|
dnl This macro is not needed if only AC_LIB_LINKFLAGS is used to locate
|
|
dnl libraries, but is otherwise very convenient.
|
|
AC_DEFUN([AC_LIB_PREFIX],
|
|
[
|
|
AC_BEFORE([$0], [AC_LIB_LINKFLAGS])
|
|
AC_REQUIRE([AC_PROG_CC])
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
AC_REQUIRE([AC_LIB_PREPARE_MULTILIB])
|
|
AC_REQUIRE([AC_LIB_PREPARE_PREFIX])
|
|
dnl By default, look in $includedir and $libdir.
|
|
use_additional=yes
|
|
AC_LIB_WITH_FINAL_PREFIX([
|
|
eval additional_includedir=\"$includedir\"
|
|
eval additional_libdir=\"$libdir\"
|
|
])
|
|
AC_ARG_WITH([lib-prefix],
|
|
[[ --with-lib-prefix[=DIR] search for libraries in DIR/include and DIR/lib
|
|
--without-lib-prefix don't search for libraries in includedir and libdir]],
|
|
[
|
|
if test "X$withval" = "Xno"; then
|
|
use_additional=no
|
|
else
|
|
if test "X$withval" = "X"; then
|
|
AC_LIB_WITH_FINAL_PREFIX([
|
|
eval additional_includedir=\"$includedir\"
|
|
eval additional_libdir=\"$libdir\"
|
|
])
|
|
else
|
|
additional_includedir="$withval/include"
|
|
additional_libdir="$withval/$acl_libdirstem"
|
|
fi
|
|
fi
|
|
])
|
|
if test $use_additional = yes; then
|
|
dnl Potentially add $additional_includedir to $CPPFLAGS.
|
|
dnl But don't add it
|
|
dnl 1. if it's the standard /usr/include,
|
|
dnl 2. if it's already present in $CPPFLAGS,
|
|
dnl 3. if it's /usr/local/include and we are using GCC on Linux,
|
|
dnl 4. if it doesn't exist as a directory.
|
|
if test "X$additional_includedir" != "X/usr/include"; then
|
|
haveit=
|
|
for x in $CPPFLAGS; do
|
|
AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"])
|
|
if test "X$x" = "X-I$additional_includedir"; then
|
|
haveit=yes
|
|
break
|
|
fi
|
|
done
|
|
if test -z "$haveit"; then
|
|
if test "X$additional_includedir" = "X/usr/local/include"; then
|
|
if test -n "$GCC"; then
|
|
case $host_os in
|
|
linux* | gnu* | k*bsd*-gnu) haveit=yes;;
|
|
esac
|
|
fi
|
|
fi
|
|
if test -z "$haveit"; then
|
|
if test -d "$additional_includedir"; then
|
|
dnl Really add $additional_includedir to $CPPFLAGS.
|
|
CPPFLAGS="${CPPFLAGS}${CPPFLAGS:+ }-I$additional_includedir"
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
dnl Potentially add $additional_libdir to $LDFLAGS.
|
|
dnl But don't add it
|
|
dnl 1. if it's the standard /usr/lib,
|
|
dnl 2. if it's already present in $LDFLAGS,
|
|
dnl 3. if it's /usr/local/lib and we are using GCC on Linux,
|
|
dnl 4. if it doesn't exist as a directory.
|
|
if test "X$additional_libdir" != "X/usr/$acl_libdirstem"; then
|
|
haveit=
|
|
for x in $LDFLAGS; do
|
|
AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"])
|
|
if test "X$x" = "X-L$additional_libdir"; then
|
|
haveit=yes
|
|
break
|
|
fi
|
|
done
|
|
if test -z "$haveit"; then
|
|
if test "X$additional_libdir" = "X/usr/local/$acl_libdirstem"; then
|
|
if test -n "$GCC"; then
|
|
case $host_os in
|
|
linux*) haveit=yes;;
|
|
esac
|
|
fi
|
|
fi
|
|
if test -z "$haveit"; then
|
|
if test -d "$additional_libdir"; then
|
|
dnl Really add $additional_libdir to $LDFLAGS.
|
|
LDFLAGS="${LDFLAGS}${LDFLAGS:+ }-L$additional_libdir"
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
fi
|
|
])
|
|
|
|
dnl AC_LIB_PREPARE_PREFIX creates variables acl_final_prefix,
|
|
dnl acl_final_exec_prefix, containing the values to which $prefix and
|
|
dnl $exec_prefix will expand at the end of the configure script.
|
|
AC_DEFUN([AC_LIB_PREPARE_PREFIX],
|
|
[
|
|
dnl Unfortunately, prefix and exec_prefix get only finally determined
|
|
dnl at the end of configure.
|
|
if test "X$prefix" = "XNONE"; then
|
|
acl_final_prefix="$ac_default_prefix"
|
|
else
|
|
acl_final_prefix="$prefix"
|
|
fi
|
|
if test "X$exec_prefix" = "XNONE"; then
|
|
acl_final_exec_prefix='${prefix}'
|
|
else
|
|
acl_final_exec_prefix="$exec_prefix"
|
|
fi
|
|
acl_save_prefix="$prefix"
|
|
prefix="$acl_final_prefix"
|
|
eval acl_final_exec_prefix=\"$acl_final_exec_prefix\"
|
|
prefix="$acl_save_prefix"
|
|
])
|
|
|
|
dnl AC_LIB_WITH_FINAL_PREFIX([statement]) evaluates statement, with the
|
|
dnl variables prefix and exec_prefix bound to the values they will have
|
|
dnl at the end of the configure script.
|
|
AC_DEFUN([AC_LIB_WITH_FINAL_PREFIX],
|
|
[
|
|
acl_save_prefix="$prefix"
|
|
prefix="$acl_final_prefix"
|
|
acl_save_exec_prefix="$exec_prefix"
|
|
exec_prefix="$acl_final_exec_prefix"
|
|
$1
|
|
exec_prefix="$acl_save_exec_prefix"
|
|
prefix="$acl_save_prefix"
|
|
])
|
|
|
|
dnl AC_LIB_PREPARE_MULTILIB creates
|
|
dnl - a variable acl_libdirstem, containing the basename of the libdir, either
|
|
dnl "lib" or "lib64" or "lib/64",
|
|
dnl - a variable acl_libdirstem2, as a secondary possible value for
|
|
dnl acl_libdirstem, either the same as acl_libdirstem or "lib/sparcv9" or
|
|
dnl "lib/amd64".
|
|
AC_DEFUN([AC_LIB_PREPARE_MULTILIB],
|
|
[
|
|
dnl There is no formal standard regarding lib and lib64.
|
|
dnl On glibc systems, the current practice is that on a system supporting
|
|
dnl 32-bit and 64-bit instruction sets or ABIs, 64-bit libraries go under
|
|
dnl $prefix/lib64 and 32-bit libraries go under $prefix/lib. We determine
|
|
dnl the compiler's default mode by looking at the compiler's library search
|
|
dnl path. If at least one of its elements ends in /lib64 or points to a
|
|
dnl directory whose absolute pathname ends in /lib64, we assume a 64-bit ABI.
|
|
dnl Otherwise we use the default, namely "lib".
|
|
dnl On Solaris systems, the current practice is that on a system supporting
|
|
dnl 32-bit and 64-bit instruction sets or ABIs, 64-bit libraries go under
|
|
dnl $prefix/lib/64 (which is a symlink to either $prefix/lib/sparcv9 or
|
|
dnl $prefix/lib/amd64) and 32-bit libraries go under $prefix/lib.
|
|
AC_REQUIRE([AC_CANONICAL_HOST])
|
|
AC_REQUIRE([gl_HOST_CPU_C_ABI_32BIT])
|
|
|
|
case "$host_os" in
|
|
solaris*)
|
|
AC_CACHE_CHECK([for 64-bit host], [gl_cv_solaris_64bit],
|
|
[AC_COMPILE_IFELSE(
|
|
[AC_LANG_SOURCE(
|
|
[[#ifdef _LP64
|
|
int ok;
|
|
#else
|
|
error fail
|
|
#endif
|
|
]])],
|
|
[gl_cv_solaris_64bit=yes],
|
|
[gl_cv_solaris_64bit=no])
|
|
]);;
|
|
esac
|
|
|
|
dnl Allow the user to override the result by setting acl_cv_libdirstems.
|
|
AC_CACHE_CHECK([for the common suffixes of directories in the library search path],
|
|
[acl_cv_libdirstems],
|
|
[acl_libdirstem=lib
|
|
acl_libdirstem2=
|
|
case "$host_os" in
|
|
solaris*)
|
|
dnl See Solaris 10 Software Developer Collection > Solaris 64-bit Developer's Guide > The Development Environment
|
|
dnl <https://docs.oracle.com/cd/E19253-01/816-5138/dev-env/index.html>.
|
|
dnl "Portable Makefiles should refer to any library directories using the 64 symbolic link."
|
|
dnl But we want to recognize the sparcv9 or amd64 subdirectory also if the
|
|
dnl symlink is missing, so we set acl_libdirstem2 too.
|
|
if test $gl_cv_solaris_64bit = yes; then
|
|
acl_libdirstem=lib/64
|
|
case "$host_cpu" in
|
|
sparc*) acl_libdirstem2=lib/sparcv9 ;;
|
|
i*86 | x86_64) acl_libdirstem2=lib/amd64 ;;
|
|
esac
|
|
fi
|
|
;;
|
|
*)
|
|
dnl If $CC generates code for a 32-bit ABI, the libraries are
|
|
dnl surely under $prefix/lib, not $prefix/lib64.
|
|
if test "$HOST_CPU_C_ABI_32BIT" != yes; then
|
|
dnl The result is a property of the system. However, non-system
|
|
dnl compilers sometimes have odd library search paths. Therefore
|
|
dnl prefer asking /usr/bin/gcc, if available, rather than $CC.
|
|
searchpath=`(if test -f /usr/bin/gcc \
|
|
&& LC_ALL=C /usr/bin/gcc -print-search-dirs >/dev/null 2>/dev/null; then \
|
|
LC_ALL=C /usr/bin/gcc -print-search-dirs; \
|
|
else \
|
|
LC_ALL=C $CC -print-search-dirs; \
|
|
fi) 2>/dev/null \
|
|
| sed -n -e 's,^libraries: ,,p' | sed -e 's,^=,,'`
|
|
if test -n "$searchpath"; then
|
|
acl_save_IFS="${IFS= }"; IFS=":"
|
|
for searchdir in $searchpath; do
|
|
if test -d "$searchdir"; then
|
|
case "$searchdir" in
|
|
*/lib64/ | */lib64 ) acl_libdirstem=lib64 ;;
|
|
*/../ | */.. )
|
|
# Better ignore directories of this form. They are misleading.
|
|
;;
|
|
*) searchdir=`cd "$searchdir" && pwd`
|
|
case "$searchdir" in
|
|
*/lib64 ) acl_libdirstem=lib64 ;;
|
|
esac ;;
|
|
esac
|
|
fi
|
|
done
|
|
IFS="$acl_save_IFS"
|
|
fi
|
|
fi
|
|
;;
|
|
esac
|
|
test -n "$acl_libdirstem2" || acl_libdirstem2="$acl_libdirstem"
|
|
acl_cv_libdirstems="$acl_libdirstem,$acl_libdirstem2"
|
|
])
|
|
# Decompose acl_cv_libdirstems into acl_libdirstem and acl_libdirstem2.
|
|
acl_libdirstem=`echo "$acl_cv_libdirstems" | sed -e 's/,.*//'`
|
|
acl_libdirstem2=`echo "$acl_cv_libdirstems" | sed -e '/,/s/.*,//'`
|
|
])
|